Implementing Load-on-Demand using ZK and Grails

{{Template:Smalltalk_Author|
|author=Chanwit Kaewkasi
|date=March 24, 2009
|version=ZK 3.6.0
}}

= Introduction =

[http://code.google.com/p/zkgrails ZK Plugin] for [http://grails.org Grails] introduces ''GroovyGrails'' mode for ZK. It seamlessly integrates ZK into the Grails stack. The plugin brings ZK and Grails to the next level of rapid RIA developement, also with convention-over-configuration, Spring, and Hibernate powers. It features:

*Accessing to Grails domain classes, transactional service classes, and a vast number of plugins.
*Quick constructing ZK components with Gabe Hicks' [http://code.google.com/p/groovy-hostel/wiki/ZkBuilder ZK Groovy Builder] syntax.
*Auto-reloading composers via Spring beans. With ZK Plugin, you can use the MVC power of ZK's composers at the same development speed as scripting ! 
*Scripting also fully supports Grails artifacts directly in .zul.
*ZUL file and composer generators.

= Example =

This is a ZKGrails port of the program written in [[Small_Talks/2008/June/Use_Load-On-Demand_to_Handle_Huge_Data | Use Load-On-Demand to Handle Huge Data]]. This tutorial is working for ZK Plugin for Grails 0.7.1 and later.

== Create a Grails project ==

You need to prepare a Grails project for this tutorial by type:

<code>$ grails create-app ondemand</code>

== Install ZKGrails ==

Next, you need to install ZKGrails. The latest version will be installed automatically, when type:

<code>$ grails install-plugin zk</code>

== Create a domain class ==

I am going to demonstrate with a simple domain class, Employee. To create domain class in Grails, simply use the command create-domain-class, following by your class name:

<code>$ grails create-domain-class employee</code>

== Adding Properties for Employee ==

I then add two properties into domain class Employee, namely fullname and username. Both are string.

<source lang="java">
class Employee {

    String fullname
    String username

    static constraints = {
    }
}
</source>

== Create a zul page ==

There are two generator scripts came with ZK Plugin for Grails. The following shows how to run create-zul to create employee.zul for you.

<code>$ grails create-zul employee</code>

This will also create grails-apps/composers/EmployeeComposer.groovy for you.

== Edit employee.zul ==

Although the generator creates a ready-to-run zul file for you from the template, but it is just a skeleton to make you easier to start with. Open employee.zul, and delete all codes below vbox, then modify it as follows.

<source lang="javascript">
<window apply="${employeeComposer}">

    <vbox>
        <image src="images/grails_logo.jpg"/>
    </vbox>

    <listbox id="lstEmployee" width="100%" checkmark="true">
        <listhead sizable="true">
            <listheader label="ID" sort="auto" />
            <listheader label="Full Name" sort="auto" />
            <listheader label="User Name" sort="auto" />
        </listhead>
    </listbox>
    <paging id="pagEmployee" pageSize="30" />

</window>
</source>

Of course, the key components which will be used in the composer are lstEmployee, and pagEmployee.

== Editing EmployeeComposer ==

From the code, you may see 2 properties lstEmployee, and pagEmployee. Both are injected by GrailsComposer, which is a subclass ofGenericForwardComposer. They, apparently, represents listbox and paging components from your .zul file.

You may notice that there is afterCompose closure. This closure is run by doAfterCompose, and it's a Groovy place to initialize your components.

The auto-wired event handle onPaging_pagEmployee will be called everytime you click pagEmployee to change the active page. Note that, the only argument of the handler must be ForwardEvent or Event to make it work.

I also show you the use of Groovy's default argument value declared at redraw method. That is, calling redraw() in afterCompose means redraw(0).

Also in redraw method, there are two places to use dynamic methods added by ZKGrails. The first one is clear
, of which removes all listitem. The second one is append, which accepts component construction via ZK Builder.

<source lang="javascript">
import org.zkoss.zkgrails.*
import org.zkoss.zk.ui.event.*

class EmployeeComposer extends GrailsComposer {

    def lstEmployee
    def pagEmployee

    def afterCompose = { c ->
        pagEmployee.totalSize = Employee.count()
        redraw()
    }

    def onPaging_pagEmployee(ForwardEvent fe) {
        def e = fe.origin
        redraw(e.activePage)
    }

    def redraw(page=0) {
        def list = Employee.list(offset: page * pagEmployee.pageSize,
                                 max: pagEmployee.pageSize)

        lstEmployee.clear()
        lstEmployee.append {
            list.each { e ->
                listitem(value: e) {
                    listcell(label: e.id)
                    listcell(label: e.fullname)
                    listcell(label: e.username)
                }
            }
        }
    }

}</source>

== Testing Data ==

Before getting your application run, you need some testing data to show. Open grails-app/conf/BootStrap.groovy, and then add the following snippet into init closure.

<source lang="javascript">
     def init = { servletContext ->
        1000.times { i ->
            new Employee(fullname: "Name $i", username: "user$i").save()
        }
     }
</source>

With the above code, we loop 1,000 times to create 1,000 domain objects of class Employee.

== Run the application ==

<code>$ grails run-app</code>

and point your browser to http://localhost:8080/ondemand/employee.zul


<comment>http://docs.zkoss.org/wiki/Implementing_Load-on-Demand_using_ZK_and_Grails</comment>


[[Category:Tutorial]]
[[Category:Other Frameworks]]
[[Category:ZK]]

{{Template:Smalltalk_Footer|
|name=Chanwit Kaewkasi
}}